图片墙的制作 - 纳金网 - Powered by Discuz!

package
{
import org.papervision3d.core.utils.Mouse3D;
import org.papervision3d.events.InteractiveScene3DEvent;
import org.papervision3d.objects.DisplayObject3D;
import org.papervision3d.view.BasicView;
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.materials.ColorMaterial;
import org.papervision3d.scenes.Scene3D;
import org.papervision3d.cameras.Camera3D;
import org.papervision3d.render.BasicRenderEngine;
import org.papervision3d.materials.*;
import org.papervision3d.view.Viewport3D;
import org.papervision3d.core.effects.view.ReflectionView;
import org.papervision3d.core.render.filter.BasicRenderFilter;
import org.papervision3d.core.utils.virtualmouse.*;
import flash.filters.*;
import flash.events.*;
import flash.display.Sprite;
import flash.utils.Dictionary;
import flash.display.Bitmap;
import flash.display.Loader;
import flash.net.URLRequest;
import com.greensock.TweenMax;
[SWF(width="640", height="480", frameRate="30", backgroundColor="0x000000")]
public class Main extends Sprite
{
private var pc:Plane = new Plane();
private var camera:Camera3D=new Camera3D();//摄影机
private var scene:Scene3D=new Scene3D();//场景
private var engine:BasicRenderEngine=new BasicRenderEngine();//渲染引擎
private var view:ReflectionView=new ReflectionView(640,480,true,true);
private var angle:Number = 0;
private var vMouse:VirtualMouse;
private var mouse3D:Mouse3D;
private var data:Dictionary = new Dictionary(true);//保存已经加载的图片
private var tempURL:String;
public function Main()
{
init3D();
}
//初始化图片位置和设置
private function init3D():void
{
var contain:DisplayObject3D = new DisplayObject3D();
var perAngle:Number = 2 * Math.PI / 20;
for (var i:int=0; i<20; i++)
{
var cm:BitmapFileMaterial = new BitmapFileMaterial("wallimages/thumbs/"+(i+1)+".jpg");
var p:Plane2D = new Plane2D(cm, 100, 100);
cm.interactive = true;
p.x = Math.cos(i * perAngle) *350;
p.z = Math.sin(i * perAngle) * 350;
p.url = "wallimages/" + (i + 1) + ".jpg";//大图片路径
p.rotationY = ( -i * perAngle) * (180 / Math.PI) + 270;//计算的偏移值
p.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, onMouseOverHandler);
p.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, onMouseOutHandler);
p.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, onMouseClickHandler);
contain.addChild(p);
}
view.scene.addChild(contain);
view.camera .z = -600;
view.camera.target = pc;
//设置反射
view.surfaceHeight =-100;
view.viewportReflection.alpha = 0.5;
view.viewportReflection.filters = [new BlurFilter(3, 3, 1)];
//vMouse = view.viewport.interactiveSceneManager.virtualMouse;
// mouse3D = view.viewport.interactiveSceneManager.mouse3D;
// Mouse3D.enabled = true;
addChild(view);
addEventListener(Event.ENTER_FRAME,render);
}
private function onMouseOverHandler(event:InteractiveScene3DEvent):void
{
}
private function onMouseOutHandler(event:InteractiveScene3DEvent):void
{
}
private function onMouseClickHandler(event:InteractiveScene3DEvent):void
{
//判断这张图片是否第一次加载
if(getImage(event.currentTarget.url)==null)
{
loadImage(event.currentTarget.url);
}
else
{
showImage(event.currentTarget.url);
}
}
//绘制底图背景
private function drawBase(bitmap:*, w:Number, h:Number, color:uint = 0xffffff):Sprite
{
var filter:DropShadowFilter=new DropShadowFilter();
filter.strength=0.3;
var shape:Sprite = new Sprite();
shape.addChild(bitmap);
shape.graphics.lineStyle(0,0,0);
shape.graphics.beginFill(color);
shape.graphics.drawRect(bitmap.x-w/60,bitmap.y-h/60,w+w/30,h+h/30);
shape.graphics.endFill();
shape.filters = [filter];
return shape;
}
//添加图片
private function addImage(id:String,obj:*):void
{
data[id] = obj;
}
//获取图片
private function getImage(id:String):*
{
return data[id];
}
//加载图片
private function loadImage(url:String):void
{
var loader:Loader = new Loader();
tempURL = url;
loader.load(new URLRequest(url))
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoadImageComplete);
}
//显示图片
private function showImage(url:String):void
{
var contain:Sprite = getImage(url);
addChild(contain);
contain.x = stage.stageWidth / 2;
contain.y = stage.stageHeight / 2;
contain.scaleX = contain.scaleY = 0;
contain.alpha = 0;
TweenMax.to(contain, 0.5, { scaleX:1, scaleY:1,alpha:1 });
}
//加载图片-- 删除监听
private function onLoadImageComplete(event:Event):void
{
event.currentTarget.removeEventListener(Event.COMPLETE, onLoadImageComplete);
var bmp:Bitmap = Bitmap(event.currentTarget.content);
bmp.x = -bmp.width / 2;
bmp.y = -bmp.height / 2;
var contain:Sprite = drawBase(bmp, bmp.width, bmp.height);
contain.addEventListener(MouseEvent.CLICK, onBackHandler);
contain.addChild(bmp);
addChild(contain);
contain.x = stage.stageWidth / 2;
contain.y = stage.stageHeight / 2;
contain.scaleX = contain.scaleY = 0;
contain.alpha = 0;
TweenMax.to(contain, 0.5, { scaleX:1, scaleY:1, alpha:1 } );
addImage(tempURL, contain);
}
private function onBackHandler(event:MouseEvent):void
{
var mc:*= event.currentTarget;
TweenMax.to(mc, 0.5, { scaleX:0, scaleY:0, alpha:0, onComplete:removeContain } );
function removeContain():void
{
removeChild(mc);
}
}
private function render(event:Event):void
{
//距离检测
var dist:Number = ((stage.mouseX) - stage.stageWidth * 0.5) * 0.005;
var dist2:Number = ((stage.mouseY) - stage.height * 0.5) *0.01;
angle += dist;
//旋转镜头
view.camera.x =600*Math.cos(angle*Math.PI/180);
view.camera.z =600*Math.sin(angle*Math.PI/180);
view.camera.fov += dist2;
if (view.camera.fov>90)
{
view.camera.fov = 90;
}
else if( view.camera.fov<50)
{
view.camera.fov = 50;
}
view.singleRender();//渲染
}
}
}
import org.papervision3d.objects.primitives.Plane;
import org.papervision3d.core.proto.MaterialObject3D;
class Plane2D extends Plane
{
//继承plane类，增加一个url 属性
public var url:String;
public function Plane2D( material:MaterialObject3D=null, width:Number=0, height:Number=0, segmentsW:Number=0, segmentsH:Number=0 )
{
super(material, width, height, segmentsW, segmentsH);
}
}

复制代码